Web Service Examples

Example 1: Accessing Iotellect Server Web Service from a PHP Script

This example shows how to get the value of a Iotellect Server context variable from a PHP script using the Web Service.

<?php
// Creating SOAP client for the server running on localhost
$client = new SoapClient("http://localhost:8080/ws/services/ServerWebService?wsdl");

$username = "admin";
$password = "admin";
$context = "users.admin";
$variable = "childInfo";

try {
    // Calling getXML Web Service function and decoding its output by URL decoder
    $childInfoXML = urldecode($client->getXML($username, $password, $context, $variable));
} catch(SoapFault $fault) {
    echo "Error occurred while calling remote function: " . $fault->faultcode . " (" . $fault->faultstring . ")";
    exit();
}

if (is_soap_fault($childInfoXML)) {
    echo "Error occurred while calling remote function: " . $fault->faultcode . " (" . $fault->faultstring . ")";
    exit();
}

// Creating DOM document from XML
$xml = new DomDocument;
$xml->loadXML($childInfoXML);

// Loading XSLT transformation
$xsl = new DomDocument;
$xsl->load('dataTable.xslt');

// Creating XSLT processor
$proc = new xsltprocessor;
$proc->importStyleSheet($xsl);

// Processing out XML document and and showing the output
echo $proc->transformToXML($xml);
?>

This script interact with a SOAP Web Service and transform the returned XML data into an HTML table using XSLT.

Creating a SOAP Client:
```
$client = new SoapClient("http://localhost:8080/ws/services/ServerWebService?wsdl");
```
This line creates a new instance of the SoapClient class in PHP, pointing to the WSDL (Web Services Description Language) file for the ServerWebService hosted on localhost on port 8080.

Credentials & Parameters Setup:

$username = "admin";
$password = "admin";
$context = "users.admin";
$variable = "childInfo";

Calling getXML Web Service Function:
```
try {
    // Calling getXML Web Service function and decoding its output by URL decoder
    $childInfoXML = urldecode($client->getXML($username, $password, $context, $variable));
} catch(SoapFault $fault) {
    echo "Error occurred while calling remote function: " . ...
}

if (is_soap_fault($childInfoXML)) {
    echo "Error occurred while calling remote function: " . ...
}
```
Make a call to the web service's getXML method with credentials (admin, admin) and parameters (users.admin, childInfo). If an error occurs during this process (such as authentication failure or network issues), it will be caught as a SoapFault, and an error message will be displayed.
The returned XML string is then URL-decoded because it was encoded according to RFC 1738 for safe transmission over SOAP.

Creating DOM Document from XML String & Loading XSLT Transformation:

$xml = new DomDocument;
$xml->loadXML($childInfoXML);
$xsl = new DomDocument;
$xsl->load('dataTable.xslt');

Create two DOMDocument objects—one for holding the retrieved XML data and another one for loading an XSLT stylesheet from dataTable.xslt (see below). The purpose of this stylesheet is to define how XML data should be transformed into HTML.

XSLT Processing & Outputting HTML Table:

$proc = new xsltprocessor;
$proc->importStyleSheet($xsl);
echo $proc->transformToXML($xml);

An instance of xsltprocessor is created which imports the loaded XSL stylesheet. It then transforms the previously loaded XML document using this style sheet definition and echoes out the resulting HTML.

By applying these transformations via $proc->transformToXML(), we turn our raw Data Table-formatted information into user-friendly table-format output ready for viewing in any web browser environment.

Example 2: Calling a Context Function

This example shows how to create a new Iotellect Server user account by calling the register function of the root context. Creation of SOAP client and error checking are omitted in this example.

$params[0]="phpuser"; // Username (value for record 0, field 0 of function input Data Table)
$params[1]="test"; // Password (value for record 0, field 1)
$params[2]="test"; // Repeat Password (value for record 0, field 2)
urldecode($client->callByStringArray("admin", "admin", "", "register", $params)); // Calling function via Web Service

Stylesheet Rules

The content of dataTable.xslt defines how each element within the original Data Table encoded in XML should be represented in HTML format:

It establishes an <xsl:template> that matches <table> elements within XML.
It uses <xsl:param> within templates to extract values based on field names.
Specific formatting rules are applied depending on field types—for example, boolean fields display green/red fonts for true/false values respectively.

Content of dataTable.xslt

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="html" encoding="UTF-8" indent="yes" />
    <xsl:template match="table">
        <table border="1">
            <tr bgcolor="silver">
                <xsl:for-each select="format/fields/field">
                    <td>
                        <xsl:choose>
                            <xsl:when test="@description">
                                <xsl:value-of select="@description" />
                            </xsl:when>
                            <xsl:otherwise>
                                <xsl:value-of select="@name" />
                            </xsl:otherwise>
                        </xsl:choose>
                    </td>
                </xsl:for-each>
            </tr>
            <xsl:for-each select="records/record">
                <xsl:call-template name="printRecord">
                    <xsl:with-param name="rec" select="self::*" />
                    <xsl:with-param name="fields"
                        select="parent::*/parent::table/format/fields" />
                </xsl:call-template>
            </xsl:for-each>
        </table>
    </xsl:template>
    <xsl:template name="printRecord">
        <xsl:param name="rec" select="0" />
        <xsl:param name="fields" select="0" />
        <tr>
            <xsl:for-each select="$fields/child::field">
                <xsl:choose>
                    <xsl:when test="$rec/value[@name=current()/@name]">
                        <xsl:call-template name="exposeFieldValue">
                            <xsl:with-param name="valueNode"
                                select="$rec/value[@name=current()/@name]" />
                            <xsl:with-param name="fieldNode" select="self::*" />
                        </xsl:call-template>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:call-template name="exposeFieldValue">
                            <xsl:with-param name="valueNode" select="child::defaultValue" />
                            <xsl:with-param name="fieldNode" select="self::*" />
                        </xsl:call-template>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:for-each>
        </tr>
    </xsl:template>
    <xsl:template name="exposeFieldValue">
        <xsl:param name="valueNode" select="0" />
        <xsl:param name="fieldNode" select="0" />
        <td>
            <xsl:choose>
                <xsl:when test="$fieldNode/child::selectionValues">
                    <xsl:choose>
                        <xsl:when
                            test="$fieldNode/selectionValues/option[text()=string($valueNode)]">
                            <xsl:value-of
                                select="$fieldNode/selectionValues/option[text()=string($valueNode)]/@description" />
                        </xsl:when>
                        <xsl:otherwise>
                            <xsl:value-of select="$valueNode" />
                        </xsl:otherwise>
                    </xsl:choose>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:choose>
                        <xsl:when test="$fieldNode/@type='B'">
                            <xsl:choose>
                                <xsl:when test="$valueNode/text()='1'">
                                    <xsl:element name="font">
                                        <xsl:attribute name="color">green</xsl:attribute>
                                        <xsl:text>true</xsl:text>
                                    </xsl:element>
                                </xsl:when>
                                <xsl:otherwise>
                                    <xsl:element name="font">
                                        <xsl:attribute name="color">red</xsl:attribute>
                                        <xsl:text>false</xsl:text>
                                    </xsl:element>
                                </xsl:otherwise>
                            </xsl:choose>
                        </xsl:when>
                        <xsl:when test="$fieldNode/@type='T'">
                            <xsl:apply-templates select="$valueNode/child::*" />
                        </xsl:when>
                        <xsl:when test="$fieldNode/@type='A'">
                            <xsl:apply-templates select="$valueNode/child::data/@name" />
                        </xsl:when>
                        <xsl:otherwise>
                            <xsl:choose>
                                <xsl:when test="not($valueNode) or not($valueNode/text())">
                                    <xsl:choose>
                                        <xsl:when
                                            test="$fieldNode/@nullable and $fieldNode/@nullable='true'">
                                            <font color="blue">Null</font>
                                        </xsl:when>
                                        <xsl:otherwise>
                                            <br />
                                        </xsl:otherwise>
                                    </xsl:choose>
                                </xsl:when>
                                <xsl:otherwise>
                                    <xsl:value-of select="$valueNode" />
                                </xsl:otherwise>
                            </xsl:choose>
                        </xsl:otherwise>
                    </xsl:choose>
                </xsl:otherwise>
            </xsl:choose>
        </td>
    </xsl:template>
</xsl:stylesheet>

DPF_EXPORT_V5.8.8 / TIME_1743710558 / 2025-04-03 20:02:38 / STRLEN_12607 / STRLEN_HTML_18066

{VERSION}

Was this page helpful?